HC-SR04. Проблема в управлении мотором.

[Jarlaxle]

Всем доброго времени суток, прошу помощи по коду Сообщества в VK не помогают, примеры не хотят компилироваться.
Пытаюсь написать код, чтобы при приближении к УЗ-датчику меньше чем на 10 см начинал работать мотор, и работал до тех пор, пока расстояние до объекта не станет больше 10 см.
Буду очень благодарен людям, которые приведут рабочий пример кода или подскажут что можно заменить.



Вот мой код, мне кажется проблема в delay после указания мотору к началу движения, т.к. после начала запуска мотора его время работы равно времени этой задержки.

Код: Выделить всё

#include <AFMotor.h>
#include "Ultrasonic.h"

Ultrasonic ultrasonic(21, 20);
AF_DCMotor motor1(4);

void setup()
{
  Serial.begin(9600);
}

void loop()
{
  float dist_cm = ultrasonic.Ranging(CM);    
  Serial.println(dist_cm);
 
  if (dist_cm < 10) 
 
  {
     motor1.run(FORWARD);
     motor1.setSpeed(255); 
     delay(1000);
  }
 
  else
  {
  motor1.run(RELEASE);
  delay(100);
  }
        
}

[noonv]

а если delay из if-а убрать?

Код: Выделить всё

void setup()
{
    Serial.begin(9600);
}

void loop()
{
    float dist_cm = ultrasonic.Ranging(CM);
    Serial.println(dist_cm);
   
    // здесь можно добавить фильтрацию
    // показаний дальномера
   
    if (dist_cm < 10)  {
        // запускаем мотор
        motor1.run(FORWARD);
        motor1.setSpeed(255);
    }
    else {
        // останавливаем мотор
    }
    delay(100);
}


[Jarlaxle]

В этом случае при выполнении условия активации мотор делает несколько оборотов и замирает Нужно чтобы вращался пока объект находится в пределах 10 см.

[noonv]

а момент когда мотор "замирает" никак не коррелирует с "пляшущими" показаниями датчика?

[Jarlaxle]

Даже если показания датчика статичны происходит тоже самое. Если вы можете, приведите пример кода (пусть и с использованием других команд) чтобы получился желаемый результат

[noonv]

Вот проверил на своём роботе (правда без adafruit-овской либы).
Так же, добавил расчёт среднего значения.

Код: Выделить всё

/*
 * test CraftDuino and L293 or L298 module
 * drive motor by US measurements
 */

#include <Ultrasonic.h>

struct MOTOR    // структура для хранения номеров pin-ов, к которым подключены моторчики
{
    int in1;      // INPUT1
    int in2;      // INPUT2
    int enable;   // ENABLE1
};

// определяем порты, к которым подключены моторчики
MOTOR MOTOR1 = { 12, 11, 10 };
MOTOR MOTOR2 = { 7, 8, 9 };

Ultrasonic ultrasonic(2, 3); // Trig - 2, Echo - 3

// число отсчётов дистанции
#define DIST_NUMBER 5
// для хранения измерений
float us_measurements[DIST_NUMBER] = {0};
int us_counter = 0; // счётчик измерения

void drive1(int speed=254);
void drive2(int speed=254);

void setup()
{
    Serial.begin(57600);

    pinMode(MOTOR1.in1, OUTPUT); // настраиваем выводы
    pinMode(MOTOR1.in2, OUTPUT); // на ВЫВОД
    pinMode(MOTOR2.in1, OUTPUT);
    pinMode(MOTOR2.in2, OUTPUT);

}

void loop()
{
    float dist_cm = ultrasonic.Ranging(CM);
    Serial.print("US: ");
    Serial.print(dist_cm);

    // накапливаем измерения
    if(us_counter < DIST_NUMBER) {
        us_measurements[us_counter] = dist_cm;
        us_counter++;
    }
    else {
        // считаем среднее значение
        us_counter = 0;
        float summ = 0;
        for(int i=0; i<DIST_NUMBER; i++) {
            summ += us_measurements[i];
        }
        dist_cm = summ/DIST_NUMBER;
        Serial.print(":");
    }

    Serial.print(" dist: ");
    Serial.println(dist_cm);

    if (dist_cm < 10)  {
        Serial.println("forward");
        // запускаем мотор
        drive1(100);
    }
    else {
        // останавливаем мотор
        Serial.println("stop");
        drive1(0);
    }
    delay(100);
}

void drive1(int speed)
{
    if(speed > 0) {
        // forward
        digitalWrite(MOTOR1.in1, HIGH);
        digitalWrite(MOTOR1.in2, LOW);
    }
    else {
        // back
        digitalWrite(MOTOR1.in1, LOW);
        digitalWrite(MOTOR1.in2, HIGH);
    }
    analogWrite(MOTOR1.enable, speed);
}

void drive2(int speed)
{
    if(speed > 0) {
        // forward
        digitalWrite(MOTOR2.in1, HIGH);
        digitalWrite(MOTOR2.in2, LOW);
    }
    else {
        // back
        digitalWrite(MOTOR2.in1, LOW);
        digitalWrite(MOTOR2.in2, HIGH);
    }
    analogWrite(MOTOR2.enable, speed);
}


[Jarlaxle]

Пожалуйста, покажи схему соединений с своем роботе. Я хочу собрать уже хоть что-нибудь, что было бы способно самостоятельно ездить огибая препятствия

[noonv]

что-то вроде этого.
Пины подключения можно углядеть в исходниках

[Jarlaxle]

Не страшно питать моторы от самой платы? Или вы использовали какой-то шилд?
Не могу подредактировать ваш скетч под свой шилд =(

[noonv]

Не страшно питать моторы от самой платы? Или вы использовали какой-то шилд?

разумеется, через шилд

[cruetly]

Привет!Пока не буду создавать тему и напишу здесь,может кто поможет.
У меня проблема, когда расстояние становится такое что ответ в течении заданного времени (по умолчанию в библиотеке стоит 1с)-не получен (тобишь я отвожу датчик на большое расстояние 1м-9999м) ардуинка начинает слать постоянно 0 метров, встроенный светодиод на 13 пине перестает моргать и горит постоянно, даже если я снова подношу руку к датчику на расстояние 0-40 см, она как бы виснет в таком положении.А если залить скеч и не убирать руку от датчика более чем на 50см то всё норм, если больше-виснет. Сейчас заметил что чихнув, я вывел ардуинку из этого состояния и она снова начала отправлять сигналы и замерять расстояния, проверил — хлопки, постукивания и прочая имитация сигнала тоже выводит его из этого состояния.В чем может быть проблема?
Arduino pro mini 5v 16mhz , Arduino IDE 1.6.1 ,использовал библиотеку Ultrasonic и скетч из этого поста - http://robocraft.ru/blog/electronics/772.html
еще пробовал скетч из этого видео http://www.youtube.com/watch?v=MrkyIOtG6ok
он там в описании к видео вставил ссылку на скетч, скетч без использования библиотеки, у меня опять же виснет если отдалить на большое расстояние, и перестает слать импульсы

[admin]

Попробуйте новую библиотеку - NewPing, которая фиксит зависание контроллера.
Это достигается установкой timeout-а (максимального ожидаемого расстояния) для функции pulseIn().

[cruetly]

Всё равно ,неужели какой-то датчик бракованный ((

[noonv]

Всё равно ,неужели какой-то датчик бракованный

всё может быть.

Как вариант - попробуйте на другие пины датчик повесить.