Всем хороша L293 кроме тока — только 600мА на канал (у L293N — 1.2А, но со внешними диодами и только кратковременно).
Но есть у неё старший брат — L298, надо сказать брат-близнец — представляет из себя те же четыре полумоста объединённые по-два сигналами разрешения работы(ENABLE),

но пожилистей — до 4А.
Корпус тоже покрупнее — при необходимости его удобно прикрепить к радиатору.
Ну и тут уже без внешних диодов никуда — придётся ставить, причём желательно шоттки и желательно на ток не меньше чем ток нагрузки.
Принципы работы, методы управления, достоинства и недостатки совершенно те же что и у L293 — можно почитать тут и тут.
А соберём ка мы на ней мотрошилд=)
Кроме рук и паяльных принадлежностей нам понадобятся:
*собственно набор L298 с необходимой обвязкой
*протошилд
*три болтовых клеммника (один для подключения питания, два — для моторов)
*немного обрезков витой пары и/или МГТФ-а

Собирать будем по такой схеме

Резисторы R1 и R2 — шунты для замера(и ограничения внешним контроллером) тока через каналы. Если мерить и ограничивать не собираетесь — можно поставить перемычки.
Получилось как-то вот так:

тут я смухлевал и воткнул конденсатор по-мельче на 16В(в комплекте идёт на 50В — чтоб перекрыть весь рабочий диапазон ЭЛЬ-ки) — влез бы и штатный еслиб я не запаял так близко друг к другу клемники для моторов=\
Нижняя каша:

Так как управление, решительно, ничем не отличается от L293 просто немного подправим скетч noonv-а для неё:

/*
 * тестовый скетч с L293/L298 
 */

struct MOTOR    // структура для хранения номеров pin-ов, к которым подключены моторчики
{
  int in1;      // INPUT1
  int in2;      // INPUT2
  int enable;   // ENABLE1
};

// определяем порты, к которым подключены моторчики
MOTOR MOTOR1 = { 2, 4, 3 };
MOTOR MOTOR2 = { 6, 7, 5 };

void setup()
{
  pinMode(MOTOR1.in1, OUTPUT); // настраиваем выводы
  pinMode(MOTOR1.in2, OUTPUT); // на ВЫВОД
  pinMode(MOTOR2.in1, OUTPUT);
  pinMode(MOTOR2.in2, OUTPUT);
}

void loop()
{
  forward1(50);   // вращаем оба моторчика вперёд на 50
  forward2(50);
  delay(3000);
  forward1(250);   // вращаем оба моторчика вперёд на 250
  forward2(250);
  delay(3000);
  back2(100);      // вращаем оба моторчика назад на 100
  back1(100); 
  delay(5000);
  forward2(40);   // а теперь опять вращаем второй моторчик вперёд
  delay(1000)
}

void forward1(int pwm) // первый вперёд
{
  digitalWrite(MOTOR1.in1, HIGH);
  digitalWrite(MOTOR1.in2, LOW);
  analogWrite(MOTOR1.enable, pwm);
}

void forward2(int pwm) // второй вперёд
{
  digitalWrite(MOTOR2.in1, HIGH);
  digitalWrite(MOTOR2.in2, LOW);
  analogWrite(MOTOR2.enable, pwm);
}

void back1(int pwm) // первый назад
{
  digitalWrite(MOTOR1.in1, LOW);
  digitalWrite(MOTOR1.in2, HIGH);
  analogWrite(MOTOR1.enable, pwm);
}

void back2(int pwm) // второй назад
{
  digitalWrite(MOTOR2.in1, LOW);
  digitalWrite(MOTOR2.in2, HIGH);
  analogWrite(MOTOR2.enable, pwm);
}

Тестируем на недостойно-хилой нагрузке=)

Работает=)
Но тратить по три пина на управление каждым каналом — жуткое расточительство — поэтому дополним наш шилд парой инверторов (подробности про принцип работы этого решения можно почитать здесь) а точнее поставим одну 74hc00

— самая распространённая микросхема логики — 4 двухвходовых элемента И-НЕ — для моторшилдов довольно стандартное решение.
Схема у нас теперь будет выглядеть так:

Шилд сверху

снизу

Также немного переделаем скетч

/*
 * тестовый скетч с L293/L298 и 74hc00
 */

struct MOTOR    // структура для хранения номеров pin-ов, к которым подключены моторчики
{
  int in;    // INVERTOR INPUT
  int enable;   // ENABLE1
};

// определяем порты, к которым подключены моторчики
MOTOR MOTOR1 = { 4, 3 };
MOTOR MOTOR2 = { 6, 5 };

int FORWARD = HIGH;
int BACK = LOW;

void setup()
{
  pinMode(MOTOR1.in, OUTPUT); // настраиваем выводы
  pinMode(MOTOR2.in, OUTPUT);
}

void loop()
{
  motor1(FORWARD, 50);   // вращаем оба моторчика вперёд на 50
  motor2(FORWARD, 50);
  delay(3000);
  motor1(FORWARD, 250);   // вертимся в раздрай на 250 (поворачиваемся)
  motor2(BACK, 250);
  delay(3000);
  motor1(BACK, 100);      // оба назад на 100
  motor2(BACK, 100); 
  delay(5000);
  motor2(FORWARD, 50);   // а теперь опять вращаем второй моторчик вперёд
  delay(1000);
}

void motor1(int dir, int pwm) // первый 
{
  digitalWrite(MOTOR1.in, dir);
  analogWrite(MOTOR1.enable, pwm);
}

void motor2(int dir, int pwm) // второй
{
  digitalWrite(MOTOR2.in, dir);
  analogWrite(MOTOR2.enable, pwm);
}

Проверяем уже на мощных моторах

Работает!
Видео результата: